صفحه 3 از 7 اولیناولین 1 2 3 4 5 6 7 آخرینآخرین
نمایش نتایج: از شماره 31 تا 45 از مجموع 92

موضوع: بانک اسکریپت پرشین نـتـورک

  
  1. #31
    نام حقيقي: amin masoudi fard

    خواننده شناسه تصویری kamelot
    تاریخ عضویت
    Dec 2009
    محل سکونت
    mashad
    نوشته
    103
    سپاسگزاری شده
    96
    سپاسگزاری کرده
    26

    اطلاعات مربوط به GP یک OU

    ممنون از همه ی دوستان

    کد:
    On Error Resume Next
    
    Set objContainer = GetObject _
        ("LDAP://ou=Sales,dc=NA,dc=fabrikam,dc=com")
     
    strGpLink = objContainer.Get("gPLink")
    intGpOptions = objContainer.Get("gPOptions")
     
    If strGpLink <;>; " " Then
        arrGpLinkItems = Split(strGpLink,"]")
        For i = UBound(arrGPLinkItems) to LBound(arrGpLinkItems) + 1 Step -1
            arrGPLink = Split(arrGpLinkItems(i-1),";")
            strDNGPLink = Mid(arrGPLink(0),9)
            WScript.Echo GetGPOName
            Select Case arrGPLink(1)
            Case 0
                WScript.Echo "No Override is cleared and the GPO is enabled."
            Case 1
                WScript.Echo "No Override is cleared and the GPO is disabled."
            Case 2
                WScript.Echo "No Override is checked and the GPO is enabled."
            Case 3
                WScript.Echo "No Override is checked and the GPO is disabled."
          End Select
        Next
        WScript.Echo VbCrLf
    End If
     
    If intGpOptions = 1 Then
        WScript.Echo "Block Policy Inheritance is checked."
    Else
        WScript.Echo "Block Policy Inheritance is not checked."
    End If
        
    Function GetGPOName
        Set objConnection = CreateObject("ADODB.Connection")  
        objConnection.Open "Provider=ADsDSOObject;"   
     
        Set objCommand = CreateObject("ADODB.Command")
        objCommand.ActiveConnection = objConnection
     
        objCommand.CommandText = _
            "<LDAP://cn=Policies,cn=System,dc=NA,dc=fabrikam,dc=com>;;" & _
                "distinguishedName,displayName;onelevel"
        Set objRecordSet = objCommand.Execute
     
        Do Until objRecordSet.EOF
            If objRecordSet.Fields("distinguishedName") = strDNGPLink Then
                GetGPOName = objRecordSet.Fields("displayName")
                objConnection.Close
                Exit Function
          End If
          objRecordSet.MoveNext
        Loop
        objConnection.Close
    End Function



    mahyar49 سپاسگزاری کرده است.

  2. #32
    نام حقيقي: Ehsan Gholami

    عضو عادی شناسه تصویری ehsan653
    تاریخ عضویت
    Aug 2009
    محل سکونت
    Tehran
    نوشته
    505
    سپاسگزاری شده
    159
    سپاسگزاری کرده
    341
    سلام
    یه فایل بت که هرچیزی رو می شه توش گنجوند برای استفاده کاربری آسون .
    البته نقص امنیتی بزرگیه .ولی خوب گفتم شاید به درد بخوره !
    ---------------------------------------------------------------------------------------
    title Import Shared Drives ver .1.0.2

    ECHO OFF
    cls
    :menu
    echo.
    echo ...........................................
    echo Import Shared Drives
    echo ...........................................
    echo.
    echo 1. Import Drives.
    echo 2. Delete Drives.
    echo 3. Exit.
    echo.
    set /p backup= Type 1, 2 or 3 then press enter:
    if %backup%==1 goto export
    if %backup%==2 goto import
    if %backup%==3 goto exit
    :export
    net use * \\server\d "user name" /"password"
    echo the command completed successfully.
    goto menu
    :import
    net use * /delete
    echo the command completed successfully.
    goto menu

    -----------------------------------------------------------------
    به جای user name باید یوزر مناسب و به جای password پسوردش نوشته بشه .
    این رو به صورت یه فایل bat ذخیره کنید کاربر بعد از اجرا با انتخاب کلید 1 آدرس مورد نظر رو روی دستگاهش مپ می کنه ،با 2 درایو حذف و با 3 پنجره بسته می شه .


    Jasad سپاسگزاری کرده است.

  3. #33
    نام حقيقي: 1234

    مدیر بازنشسته
    تاریخ عضویت
    Jul 2009
    محل سکونت
    5678
    نوشته
    5,634
    سپاسگزاری شده
    2513
    سپاسگزاری کرده
    272
    تعیین OS ویندوز

    This Windows PowerShell script uses WMI to determine the OS Version ex: Windows XP, Windows Vista, etc. You can target a remote computer to reteive its information as well

    WindowsPowerShell

    کد:
    Param($computer = "localhost")
    
    
    
    Function Get-OSVersion($computer,[ref]$osv)
    
    {
    
     $os = Get-WmiObject -class Win32_OperatingSystem `
    
           -computerName $computer
    
     Switch ($os.Version)
    
      {
    
        "5.1.2600" { $osv.value = "xp" }
    
        "5.1.3790" { $osv.value = "2003" }
    
        "6.0.6001" 
    
                   {
    
                     If($os.ProductType -eq 1)
    
                       {
    
                        $osv.value = "Vista"
    
                       } #end if
    
                     Else
    
                       {
    
                        $osv.value = "2008"
    
                       } #end else
    
                   } #end 6001
    
        "6.1.7600"
    
                    {
    
                     If($os.ProductType -eq 1)
    
                       {
    
                        $osv.value = "Win7"
    
                       } #end if
    
                     Else
    
                       {
    
                        $osv.value = "2008R2"
    
                       } #end else
    
                   } #end 7600
    
         DEFAULT { "Version not listed" }
    
      } #end switch
    
    } #end Get-OSVersion
    
    
    
    # *** entry point to script ***
    
    $osv = $null
    
    Get-OSVersion -computer $computer -osv ([ref]$osv)
    
    $osv



    ویرایش توسط patris1 : 2010-02-22 در ساعت 02:58 AM
    mahyar49 سپاسگزاری کرده است.

  4. #34
    نام حقيقي: حمید قنبریان

    خواننده
    تاریخ عضویت
    Oct 2009
    محل سکونت
    کرج
    نوشته
    501
    سپاسگزاری شده
    522
    سپاسگزاری کرده
    203

    اضافه کردن فونت

    با سلام و درود خدمت همه عزیزان

    از این اسکریپت برای اضافه کردن یک فونت در سیستم استفاده میشود .

    کد:
    'Fontadd.vbs
    Dim RootDse, RootPath 
    Dim ouComputers, Computer, oComputerList
    Dim oPing, objStatus, oFso
    Dim UpdateSourceDir, sCmd, FontFile
    'this directory should contain this script,
    'the font file to push, and the installfont.vbs file
    UpdateSourceDir = "d:\NewFont"
    FontFile = "Mitra.TTF"
    Set RootDse = GetObject("ldap://RootDse")
    RootPath = "OU=Computers,OU=fabrikam," & RootDse.get("DefaultNamingContext")
    'need a filesystem object to do the copy stuff
    Set oFso = CreateObject("Scripting.FileSystemObject")
     
    'the command to be executed in a remote process
    sCmd = "c:\windows\system32\cscript.exe c:\temp\installfont.vbs " & UpdateSourceDir & "\" & FontFile & " //B"    
    'get the list of computers to enumerate through
    Set oComputerList = GetObject("LDAP://" & RootPath)
    For Each Computer In oComputerList
            'if the computer is alive then perform the update
            Set oPing = GetObject("winmgmts:{impersonationLevel=impersonate}")._
                ExecQuery("select * from Win32_PingStatus where address = '"_
                & Computer.Name & "'")
                For Each objStatus in oPing
                    If Not IsNull(objStatus.StatusCode) And objStatus.StatusCode = 0 Then 
                            'perform the steps needed for the update
                            UpdateTargetDir = "\\" & Computer.Name & "\c$\temp"
     
                            'make sure the target directory exists
                            If Not oFso.FolderExists(UpdateTargetDir) Then
                                oFso.CreateFolder(UpdateTargetDir)
                            End If
     
                            'copy the font file to the remote computer
                            oFso.CopyFile UpdateSourceDir & "\" & FontFile, UpdateTargetDir & "\" & FontFile
                            'copy the script that installs the font to the remote computer
                            oFso.CopyFile UpdateSourceDir & "\installfont.vbs", UpdateTargetDir & "\installfont.vbs"
                            'grab a handle to a process on the remote computer
                            Set oTarget = GetObject("winmgmts:{impersonationLevel=impersonate}!" & _
                                          "\\" & Computer.Name & "\root\cimv2:Win32_Process")
                          'fire the script in a remote process
                          iResult = oTarget.Create("cmd /c " & sCmd ,,,iProcId)
                    End If
                  Next     
    Next
     
    'contents of the installfont.vbs file 
    Const FONTS = &H14&
    Dim oShell, oFolder
    'the caller should include the path to the font file to be installed
    If Wscript.Arguments.Count = 1 Then
        Set oShell = CreateObject("Shell.Application")
        Set oFolder = oShell.Namespace(FONTS)
        oFolder.CopyHere Wscript.Arguments(0)
    Else
        Wscript.Quit
    End If



    mahyar49 سپاسگزاری کرده است.

  5. #35
    نام حقيقي: +++AnathemA+++

    عضو ویژه شناسه تصویری mahyar49
    تاریخ عضویت
    May 2009
    محل سکونت
    021
    نوشته
    913
    سپاسگزاری شده
    879
    سپاسگزاری کرده
    673
    سلام
    پاک کردن کامل محتوای Event Viewer
    این اسکریپت کاملا Event Viewer را تخلیه می کند...

    محتوای زیر را در یک فایل vbs ذخیره کنید...

    کد:
     
    strComputer = "." 
    Set oWMIService = GetObject("winmgmts:" _ 
    & "{impersonationLevel=impersonate,(Security)}!\\" & _ 
    strComputer & "\root\cimv2" ) 
    Set cLogFiles = oWMIService.ExecQuery _ 
    ("SELECT * FROM Win32_NTEventLogFile" ) 
    For Each oLogfile in cLogFiles 
    oLogFile.ClearEventLog() 
    Next



    SADEGH65، mmj و hosseini-n سپاسگزاری کرده‌اند.

  6. #36
    نام حقيقي: 1234

    مدیر بازنشسته
    تاریخ عضویت
    Jul 2009
    محل سکونت
    5678
    نوشته
    5,634
    سپاسگزاری شده
    2513
    سپاسگزاری کرده
    272
    فعال کردن تشخیص Gateway کار افتاده

    Enable Dead Gateway Detection for All Network Adapters

    VBScript

    کد:
    On Error Resume Next
    
    strComputer = "."
    Set objWMIService = GetObject("winmgmts:" _
        & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
    
    Set objNetworkSettings = objWMIService.Get("Win32_NetworkAdapterConfiguration")
    objNetworkSettings.SetDeadGWDetect(True)



    SADEGH65 و amir_vh سپاسگزاری کرده‌اند.

  7. #37
    نام حقيقي: 1234

    مدیر بازنشسته
    تاریخ عضویت
    Jul 2009
    محل سکونت
    5678
    نوشته
    5,634
    سپاسگزاری شده
    2513
    سپاسگزاری کرده
    272
    درست کردن route با استفاده ازDNS

    Create a Route Through DNS Record

    VBScript
    کد:
    strDNSServer = "atl-dc-03.fabrikam.com"
    strContainer = "fabrikam.com"
    strOwner = "atl-srv-01.fabrikam.com"
    intRecordClass = 1
    intTTL = 600 
    intPreference = 1
    strRouter = "router.fabrikam.com"
     
    strComputer = "."
    Set objWMIService = GetObject("winmgmts:" _
        & "{impersonationLevel=impersonate}!\\" & strComputer & _
            "\root\MicrosoftDNS")
    
    Set objItem = objWMIService.Get("MicrosoftDNS_RTType")
    errResult = objItem.CreateInstanceFromPropertyData _
        (strDNSServer, strContainer, strOwner, intRecordClass, _
            intTTL, intPreference, strRouter)



    SADEGH65 سپاسگزاری کرده است.

  8. #38
    نام حقيقي: 1234

    مدیر بازنشسته
    تاریخ عضویت
    Jul 2009
    محل سکونت
    5678
    نوشته
    5,634
    سپاسگزاری شده
    2513
    سپاسگزاری کرده
    272
    بدست آوردن WAN IP از روتر Linksys WRT54G

    Retrieve a WAN IP Address From a Broadband Router

    (Queries a broadband router for a WAN IP Address and, if needed, updates the address stored in the registry)

    VBScript
    کد:
    'Broadband Router WAN-IP Address Retrieval.  
    '(c) 2006, Dr. F.M. (Mike) Covington, LanCanyon Labs
    'SAMPLE / EXAMPLE VBScript Code
    '=============================================================
    
    'This script retrieves the external DHCP WAN IP address from a Linksys WRT54G Broadband
    'Router and checks it against the previously retrieved IP address stored in a Registry key.
    'If the two IP addresses do not match, it updates the stored IP address in the Registry and
    'then sends a text message to a cell phone, indicating the new IP address.
    'This should be run as Administrator as a scheduled (hourly) task for automated checking.
    ==============================================================
    
    Set objShell = CreateObject("wscript.shell")
    
    Set xml = CreateObject("Microsoft.XMLHTTP")
    
    'NOTE: Replace all placeholders with appropriate addresses, names, passwords, etc.
    
    
    'Replace the below Broadband Router's internal IP address, 
    '    administrator's name, and password, as necessary"
    
    
    xml.Open "GET", "http://192.168.1.100/StaRouter.htm", True, "administrator","admin"
    
    xml.Send
    
    
    'The following line gives the router's script code time to retrieve the WAN address.
    
    wscript.sleep 2000
    
    'The code below locates the IP address in the returned HTML and then 
    
    'performs some text formatting to ensure that only the address is returned.
    
    x=15
    
    IP = mid(xml.responsetext,instr(xml.responsetext,"var wan_ip = ")+14,x)
    
    do while instr(IP,"""")
    
        x=x-1
    
        IP=mid(IP,1,x)
    
    loop
    
    'check for IP change and store new IP if changed
    
    x = objshell.regread("HKLM\Software\OfficeIP\CurrentIP")
    
    objshell.regwrite "HKLM\Software\OfficeIP\LastCheck",date & " @ " & time
    
    If x <> IP then
    
        objshell.regwrite "HKLM\Software\OfficeIP\CurrentIP",IP
    
       'Send IP as text message to cell phone
    
        set objEMail=createobject("cdo.message")
    
        objemail.to = "PLACEHOLDER: Your Cell Phone's Text Msg Address Here"
    
        objemail.from = "PLACEHOLDER: Your PC's (or your) E-mail Address Here"
    
        objemail.subject = "IP Info"
    
        objemail.textbody = "WAN-IP:" &vbcrlf& IP
    
        objEmail.Configuration.Fields.Item _
            ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    
        objEmail.Configuration.Fields.Item _
            ("http://schemas.microsoft.com/cdo/configuration/smtpserver") _
                = "PLACEHOLDER: Your SMTP Server's Address Here" 
    
        objEmail.Configuration.Fields.Update
    
        objEmail.Send
    
    end if



    ARM سپاسگزاری کرده است.

  9. #39
    نام حقيقي: 1234

    مدیر بازنشسته
    تاریخ عضویت
    Jul 2009
    محل سکونت
    5678
    نوشته
    5,634
    سپاسگزاری شده
    2513
    سپاسگزاری کرده
    272
    List Computer System BIOS Properties


    کد:
    #This code demonstrates how to list Computer System BIOS information for the local system 
    #without any plug-ins. 
    #
    #To run this script within your environment you should only need to copy and paste this script into
    #either Windows Powershell ISE or PowerGUI Script Editor,(http://powergui.org) with the following
    #changes to the script which I have numbered below.  
    #  1.) You may also need to install Microsoft Update "http://support.microsoft.com/kb/968930".
    #
    # You may change the "." to a computer name, (example: "ComputerName") to get remote system information
    
    $strComputer = "."
    
    $objWin32Bios = Get-WmiObject -Class Win32_BIOS -namespace "root\CIMV2" -computername $strComputer
    foreach ($objBiosItem in $objWin32Bios)
    {
      Write-Host "BIOSVersion:" $objBiosItem.BIOSVersion
      Write-Host "BuildNumber:" $objBiosItem.BuildNumber
      Write-Host "Caption:" $objBiosItem.Caption
      Write-Host "CurrentLanguage:" $objBiosItem.CurrentLanguage
      Write-Host "Description:" $objBiosItem.Description
      Write-Host "InstallableLanguages:" $objBiosItem.InstallableLanguages
      Write-Host "InstallDate:" $objBiosItem.InstallDate
      Write-Host "ListOfLanguages:" $objBiosItem.ListOfLanguages
      Write-Host "Manufacturer:" $objBiosItem.Manufacturer
      Write-Host "Name:" $objBiosItem.Name
      Write-Host "PrimaryBIOS:" $objBiosItem.PrimaryBIOS
      Write-Host "ReleaseDate:" $objBiosItem.ReleaseDate
      Write-Host "SerialNumber2:" $objBiosItem.SerialNumber
      Write-Host "SMBIOSBIOSVersion:" $objBiosItem.SMBIOSBIOSVersion
      Write-Host "SMBIOSMajorVersion:" $objBiosItem.SMBIOSMajorVersion
      Write-Host "SMBIOSMinorVersion:" $objBiosItem.SMBIOSMinorVersion
      Write-Host "SMBIOSPresent:" $objBiosItem.SMBIOSPresent
      Write-Host "SoftwareElementID:" $objBiosItem.SoftwareElementID
      Write-Host "SoftwareElementState:" $objBiosItem.SoftwareElementState
      Write-Host "Status:" $objBiosItem.Status
      Write-Host "TargetOperatingSystem:" $objBiosItem.TargetOperatingSystem
      Write-Host "Version:" $objBiosItem.Version
    
    }



    ARM سپاسگزاری کرده است.

  10. #40
    نام حقيقي: 1234

    مدیر بازنشسته
    تاریخ عضویت
    Jul 2009
    محل سکونت
    5678
    نوشته
    5,634
    سپاسگزاری شده
    2513
    سپاسگزاری کرده
    272
    Collect Hostname, IP and MAC to populate DHCP Scope


    This script can read an input file to scan the list and use WMI to get the hostname, ip and MAC. It's very usefull to populate DHCP scopes with that information
    VBScript
    کد:
    On Error Resume Next
    Dim fso
    Dim tst
    Dim objTS
    Dim strMachineName
    
    Set fso = createObject("Scripting.FileSystemObject")
    
    'here is where you will provide the ip list to get the mac information
    
    Set tst = fso.OpenTextFile("C:\iprange.txt", 1, false)
    
    While Not tst.AtEndOfStream
                    strMachineName = tst.readLine
                    
                    echoMAC strMachineName
    Wend
    
    Sub echoMAC(strComputer)
    
                    On error resume next
                    If strComputer <> "" Then
                                   strInput = True
                    End if
    
                    Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
    
    
                    Set colItems = objWMIService.ExecQuery _
                                   ("Select * From Win32_NetworkAdapterConfiguration Where IPEnabled = True")
    
                    For Each objItem in colItems
    
    'you can use wscript.write, instead of wscript.echo to save the information on a file 
                                  wscript.echo objItem.dnshostname & ";" & objItem.IPAddress(0) & ";" & objItem.MACAddress
    
                    Next
    End Sub



    ARM سپاسگزاری کرده است.

  11. #41
    نام حقيقي: 1234

    مدیر بازنشسته
    تاریخ عضویت
    Jul 2009
    محل سکونت
    5678
    نوشته
    5,634
    سپاسگزاری شده
    2513
    سپاسگزاری کرده
    272
    Remotely execute cmd.exe commands on multiple computers


    if it works in cmd.exe , you can remotely execute on multiple servers .this script invokes whatever command you can use in cmd.exe on one or more computers
    you input the command you'd like to run as a screen input when you run the script
    you can use all cmd.exe command like [del,ipconfig /flushdns,ipconfig /registerdns,gpupdate /force ,notepad.exe,defrag c:, wuauclt /detectnow , powercfg, net start ,net stop,copy,arp,wscript.exe ....] i am just giving you ideas what you can do with it
    Windows Powershell
    کد:
    # ==============================================================================================
    #  
    # Script Name : Run Remote cmd.exe Commands
    # 
    # AUTHOR: Mohamed Garrana 
    # DATE  : 4/12/2010
    # 
    # COMMENT: 
    # this script invokes whatever command you can use in cmd.exe on one or more computers
    #you input the command name as a screen input when you run the script
    #you can use all cmd.exe command like [del,ipconfig /flushdns,ipconfig /registerdns,gpupdate /force ,notepad.exe,defrag c:, ...
    #..wuauclt /detectnow,powercfg,net start ,net stop,copy,arp,wscript.exe ....]
    #if you can do it from cmd.exe you can do it here on multiple computers at the same time
    # ==============================================================================================
    
    
    function Run-RemoteCMD {
    
    	param(
    	[Parameter(Mandatory=$true,valuefrompipeline=$true)]
    	[string]$compname)
    	begin {
    		$command = Read-Host " Enter command to run"
    		[string]$cmd = "CMD.EXE /C " +$command
    						}
    	process {
    		$newproc = Invoke-WmiMethod -class Win32_process -name Create -ArgumentList ($cmd) -ComputerName $compname
    		if ($newproc.ReturnValue -eq 0 )
    				{ Write-Output " Command $($command) invoked Sucessfully on $($compname)" }
    				# if command is sucessfully invoked it doesn't mean that it did what its supposed to do
    				#it means that the command only sucessfully ran on the cmd.exe of the server
    				#syntax errors can occur due to user input 
    	
    	
    	
    	
    	}
    	End{Write-Output "Script ...END"}
    	 			}
    	
    
    #----------------
    #you can use this script to run any command that can be run on CMD.EXE
    #the following is only to give you an idea how can you use it
    #-----------------
    #for copying files from many remote computers to a single
    # get-content c:\servers.txt | Run-Remotecommand
    #Enter command to run: copy c:\log\log.txt d:\
    #you only input "copy c:\log\log.txt d:\"
    #---------------------------------------
    #for forcing group policy update on multiple computers
    # get-content c:\servers.txt | Run-Remotecommand
    #Enter command to run: gpupdate /force
    #--------------------------------------
    #for stopping the Bits service on multiple computers
    # get-content c:\servers.txt | Run-Remotecommand
    #Enter command to run: Net stop bits
    #---------
    #you can always run it against a single server using 
    #Run-RemoteCommand server1
    #Enter command to run: enter whatever you'd normally enter in cmd.exe shell



    ARM سپاسگزاری کرده است.

  12. #42
    نام حقيقي: 1234

    مدیر بازنشسته
    تاریخ عضویت
    Jul 2009
    محل سکونت
    5678
    نوشته
    5,634
    سپاسگزاری شده
    2513
    سپاسگزاری کرده
    272
    VBScript to Export Users & Groups SIDs to an Excel Spreadsheet



    The script will convert objectSID to S-1-5-21-xxx format and save the user/group names alongwith their SID values to an Excel Spreadsheet
    VBScript
    کد:
    On Error Resume Next
    
    strFileName = "Users-Groups-SIDs.xlsx"
    
    Set objShell = CreateObject("Wscript.Shell")
    
    strPath = Wscript.ScriptFullName
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    
    Set objFile = objFSO.GetFile(strPath)
    strFolder = objFSO.GetParentFolderName(objFile)
    
    
    SET objExcelApp = CREATEOBJECT("Excel.Application")
    SET objWB = objExcelApp.Workbooks.Add
    SET objExcel = objWB.Worksheets(1)
    
    objWB.SaveAs(strFolder & "\" & strFileName)
    
    Const ADS_SCOPE_SUBTREE = 2
    
    Set objConnection = CreateObject("ADODB.Connection")
    Set objCommand =   CreateObject("ADODB.Command")
    objConnection.Provider = "ADsDSOObject"
    objConnection.Open "Active Directory Provider"
    Set objCommand.ActiveConnection = objConnection
    
    objCommand.Properties("Page Size") = 1000
    objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 
    
    'Set the path of the file to the same folder of the script
    'Open the file and make the workbook visible
    Set objExcel = CreateObject("Excel.Application")
    Set objWorkbook = objExcel.Workbooks.Open(strFolder & "\" & strFileName)
    objExcel.Visible = True
    
    objExcel.Cells(1, 1).Value = "Name"
    objExcel.Cells(1, 1).Font.Bold = TRUE
    objExcel.Columns(1).ColumnWidth = 40
    objExcel.Cells(1, 2).Value = "Security ID"
    objExcel.Cells(1, 2).Font.Bold = TRUE
    objExcel.Columns(2).ColumnWidth = 60
    
    'Starting row of the Excel is 2, since first row are column headings
    y = 2
    
    
    objCommand.CommandText = _
        "SELECT * FROM 'LDAP://dc=nicwan,dc=moi,dc=gov' WHERE objectCategory='user'"  
    Set objRecordSet = objCommand.Execute
    
    
    objRecordSet.MoveFirst
       Do Until objRecordSet.EOF
    
          strADsPathUser = objRecordSet.Fields("ADsPath").Value
          'wScript.echo strADsPathUser 
          Set objUser = GetObject(strADsPathUser)
    
          objExcel.Cells(y,1) = objUser.sAMAccountName
          'Wscript.Echo objUser.sAMAccountName
    
          intUserSID = fnGet_HexString(objUser.ObjectSID)           
    
          objExcel.Cells(y,2) = intUserSID  
          'Wscript.Echo intUserSID
    
          y = y + 1
          objRecordSet.MoveNext
       Loop
    
    objCommand.CommandText = _
        "SELECT * FROM 'LDAP://dc=nicwan,dc=moi,dc=gov' WHERE objectCategory='group'"  
    Set objRecordSet = objCommand.Execute
    
    
    objRecordSet.MoveFirst
       Do Until objRecordSet.EOF
    
          strADsPathGroup = objRecordSet.Fields("ADsPath").Value
          'wScript.echo strADsPathGroup 
          Set objGroup = GetObject(strADsPathGroup)
    
          'if objGroup.groupType = "-2147483646" then
          objExcel.Cells(y,1) = objGroup.sAMAccountName
          'Wscript.Echo objUser.sAMAccountName
    
          intGroupSID = fnGet_HexString(objGroup.ObjectSID)          
    
          objExcel.Cells(y,2) = intGroupSID  
          'Wscript.Echo intUserSID
          'End if
          y = y + 1
          objRecordSet.MoveNext
       Loop
    
    objRecordSet.Close
    objConnection.Close
    
    SET objSheet = NOTHING
    SET objWB =  NOTHING
    objExcelApp.Quit()
    SET objExcelApp = NOTHING
    
    Wscript.echo "Script Finished..."
    
    
    Function fnGet_HexString(intSID)    
      Dim strRet, i, b    
      strRet = ""
         
      For i = 0 to Ubound(intSID)        
       b = hex(ascb(midb(intSID,i+1,1)))        
       If( len(b) = 1 ) then b = "0" & b           
        strRet = strRet & b    
      Next        
    
      fnGet_HexString = fnHexStrToDecStr(strRet)    
    End Function
    
    Function fnHexStrToDecStr(strSid)  
      Dim arrbytSid, lngTemp, j 
      ReDim arrbytSid(Len(strSid)/2 - 1) 
    
      For j = 0 To UBound(arrbytSid)     
       arrbytSid(j) = CInt("&H" & Mid(strSid, 2*j + 1, 2)) 
      Next 
    
      fnHexStrToDecStr = "S-" & arrbytSid(0) & "-" & arrbytSid(1) & "-" & arrbytSid(8) 
      lngTemp = arrbytSid(15) 
      lngTemp = lngTemp * 256 + arrbytSid(14) 
      lngTemp = lngTemp * 256 + arrbytSid(13) 
      lngTemp = lngTemp * 256 + arrbytSid(12) 
    
      fnHexStrToDecStr = fnHexStrToDecStr & "-" & CStr(lngTemp) 
    
      lngTemp = arrbytSid(19) 
      lngTemp = lngTemp * 256 + arrbytSid(18) 
      lngTemp = lngTemp * 256 + arrbytSid(17) 
      lngTemp = lngTemp * 256 + arrbytSid(16) 
    
      fnHexStrToDecStr = fnHexStrToDecStr & "-" & CStr(lngTemp) 
    
      lngTemp = arrbytSid(23) 
      lngTemp = lngTemp * 256 + arrbytSid(22) 
      lngTemp = lngTemp * 256 + arrbytSid(21) 
      lngTemp = lngTemp * 256 + arrbytSid(20) 
    
      fnHexStrToDecStr = fnHexStrToDecStr & "-" & CStr(lngTemp) 
    
      lngTemp = arrbytSid(25) 
      lngTemp = lngTemp * 256 + arrbytSid(24) 
    
      fnHexStrToDecStr = fnHexStrToDecStr & "-" & CStr(lngTemp) 
    End Function



    ARM سپاسگزاری کرده است.

  13. #43
    نام حقيقي: 1234

    مدیر بازنشسته
    تاریخ عضویت
    Jul 2009
    محل سکونت
    5678
    نوشته
    5,634
    سپاسگزاری شده
    2513
    سپاسگزاری کرده
    272
    Write Print Server Information to an Excel Spreadsheet


    VBScript
    کد:
    ' Access a print server, get information about all printers on the server,
    ' and build an Excel spreadsheet with the information.  You must have power
    ' user or Administrator rights to the print server, and need to have 
    ' Microsoft Excel installed on the PC you are running this from.
    ' Sorry, it is not well commented, but something had to give in order to make it fit in 150 lines.
    ' Randy R - 1-22-07
    
    On Error Resume Next
    
    Dim strComputer, strExcelPath, objExcel, objSheet, k, objGroup
    Dim objWMIService, colItems, ErrState, Sheet, strPorts, strPortNum
    
    'Sheet = spreadsheet page, k = row in sheet
    Sheet = 1
    k = 2
    
    strComputer = InputBox ("Please type the print server name to check, " & vbCrLf & _
       "Else enter ALL for all print servers", "Server Name","CCPS01")
    
    if strComputer = "" then
      WScript.quit
    end if
    
    strExcelPath = InputBox ("Please enter the path to save file to: ", "File path", "F:\")
    strExcelPath = strExcelPath & "Printers_" & strComputer & ".xls"
    
    ' Bind to Excel object.
    On Error Resume Next
    Set objExcel = CreateObject("Excel.Application")
    If Err.Number <> 0 Then
      On Error GoTo 0
      Wscript.Echo "Excel application not found."
      Wscript.Quit
    End If
    
    On Error GoTo 0
    
    ' Create a new workbook.
    objExcel.Workbooks.Add
    
    'Change this to fit your server situation
    Select Case UCase(strComputer)
      Case "ALL"
        PrintServer("CCPS01")
        Sheet = Sheet + 1
        PrintServer("CCPS02")
        Sheet = Sheet + 1
        PrintServer("ServerPS03")
      Case Else
        PrintServer(strComputer)
    End Select
    
    Function PrintServer(strComputer)
    
    k=2
    Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
    Set colItems = objWMIService.ExecQuery("Select * from Win32_Printer",,48)
    Set colPorts =  objWMIService.ExecQuery("Select * from Win32_TCPIPPrinterPort")
    Set strPorts = CreateObject("Scripting.Dictionary")
    Set strPortNum = CreateObject("Scripting.Dictionary")
    
    For Each objPort in colPorts
    strPorts.add objPort.Name, objPort.HostAddress
    strPortNum.add objPort.Name, objPort.PortNumber
    Next
    
    ' Bind to worksheet.
    Set objSheet = objExcel.ActiveWorkbook.Worksheets(Sheet)
    objSheet.Name = strComputer
    
    ' Populate spreadsheet cells with printer attributes.
    objSheet.Cells(1, 1).Value = "Name"
    objSheet.Cells(1, 2).Value = "ShareName"
    objSheet.Cells(1, 3).Value = "Comment"
    objSheet.Cells(1, 4).Value = "Error"
    objSheet.Cells(1, 5).Value = "DriverName"
    objSheet.Cells(1, 6).Value = "EnableBIDI"
    objSheet.Cells(1, 7).Value = "JobCount"
    objSheet.Cells(1, 8).Value = "Location"
    objSheet.Cells(1, 9).Value = "PortName"
    objSheet.Cells(1, 10).Value = "PortAddress"
    objSheet.Cells(1, 11).Value = "PortNumber"
    objSheet.Cells(1, 12).Value = "Published"
    objSheet.Cells(1, 13).Value = "Queued"
    objSheet.Cells(1, 14).Value = "Shared"
    objSheet.Cells(1, 15).Value = "Status"
    
    For Each objItem in colItems
    'put error code into human readable form
    Select Case objItem.DetectedErrorState
      Case 4
        ErrState = "Out of Paper"
      Case 5
        ErrState = "Toner low"
      Case 6
        ErrState = "Printing"
      Case 9
        ErrState = "Offline"
      Case Else
        ErrState = objItem.DetectedErrorState
    End Select
    
    'populate the row with this printer's data
    objSheet.Cells(k, 1).Value = objItem.Name
    objSheet.Cells(k, 2).Value = objItem.ShareName
    objSheet.Cells(k, 3).Value = objItem.Comment
    objSheet.Cells(k, 4).Value = ErrState
    objSheet.Cells(k, 5).Value = objItem.DriverName
    objSheet.Cells(k, 6).Value = objItem.EnableBIDI
    objSheet.Cells(k, 7).Value = objItem.JobCountSinceLastReset
    objSheet.Cells(k, 8).Value = objItem.Location
    objSheet.Cells(k, 9).Value = objItem.PortName
    objSheet.Cells(k, 10).Value = strPorts.Item(objItem.PortName)
    objSheet.Cells(k, 11).Value = strPortNum.Item(objItem.PortName)
    objSheet.Cells(k, 12).Value = objItem.Published
    objSheet.Cells(k, 13).Value = objItem.Queued
    objSheet.Cells(k, 14).Value = objItem.Shared
    objSheet.Cells(k, 15).Value = objItem.Status
    
    k = k + 1
    Next
    
    ' Format the spreadsheet.
    objSheet.Range("A1:M1").Font.Bold = True
    objSheet.Select
    objSheet.Range("A2").Select
    objExcel.ActiveWindow.FreezePanes = True
    objExcel.Columns(3).ColumnWidth = 25
    objExcel.Columns(5).ColumnWidth = 25
    objExcel.Columns(6).ColumnWidth = 10
    objExcel.Columns(8).ColumnWidth = 30
    objExcel.Columns(1).ColumnWidth = 20
    objExcel.Columns(9).ColumnWidth = 20
    objExcel.Columns(10).ColumnWidth = 15
    objExcel.Columns(2).ColumnWidth = 15
    End Function
    
    ' Save the spreadsheet and close the workbook.
    objExcel.ActiveWorkbook.SaveAs strExcelPath
    objExcel.ActiveWorkbook.Close
    
    ' Quit Excel.
    objExcel.Application.Quit
    
    ' Clean Up
    Set objUser = Nothing
    Set objGroup = Nothing
    Set objSheet = Nothing
    Set objExcel = Nothing
    
    WScript.Echo "Printer listing



    ARM سپاسگزاری کرده است.

  14. #44
    نام حقيقي: 1234

    مدیر بازنشسته
    تاریخ عضویت
    Jul 2009
    محل سکونت
    5678
    نوشته
    5,634
    سپاسگزاری شده
    2513
    سپاسگزاری کرده
    272
    Modify User Information



    Provides a graphical user interface enabling users who have the appropriate permissions to edit selected personal details of employees (in this case, job title, department, and manager).
    VBScript
    کد:
    <head>
    <title>Staff details editor</title>
    <HTA:APPLICATION
         APPLICATIONNAME="Staff details editor"
         SCROLL="YES"
         SINGLEINSTANCE="YES"
    >
    </head>
    
    <script language="VBScript">
    Const strDomainPath = "ou=Staff,dc=Contoso,dc=com"
    
    Sub StaffSelected
      strStaffLDAP = StaffDropDown.Value
      Set objUser = GetObject(strStaffLDAP)
    
      ' If the employee has a manager defined, prefix the string with "LDAP://" to make it easier to compare against ADsPath strings
      If objUser.Manager<>"" Then
        strManagerLDAP = "LDAP://" & objUser.Manager
      End If
    
      ' Build the form HTML
      strSpanHTML = "<p>Job title: <input type=" & Chr(34) & "text" & Chr(34) & " name=" & Chr(34) & "JobTitle" & Chr(34) & " size=50><br>"
      strSpanHTML = strSpanHTML & "Manager: <select name=" & Chr(34) & "ManagerDropDown" & Chr(34) & "></select><br>"
      strSpanHTML = strSpanHTML & "Department: <input type=" & Chr(34) & "text" & Chr(34) & " name=" & Chr(34) & "Department" & Chr(34) & "></p>"
      strSpanHTML = strSpanHTML & "<p><input class=" & Chr(34) & "button" & Chr(34) & " type=" & Chr(34) & "button" & Chr(34) & " value=" & Chr(34) & "Save changes" & Chr(34) & " onClick=" & Chr(34) & "SaveButton" & Chr(34) & ">&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;"
      strSpanHTML = strSpanHTML & "<input class=" & Chr(34) & "button" & Chr(34) & " type=" & Chr(34) & "button" & Chr(34) & " value=" & Chr(34) & "Cancel" & Chr(34) & " onClick=" & Chr(34) & "CancelButton" & Chr(34) & "></p>"
    
      ' Plonk it onto the page
      Output.InnerHTML = strSpanHTML
    
      ' Build the Manager drop-down list
      ' We can do this by copying the staff list, since it is going to be the same list of names
      For Each objOption in StaffDropDown.Options
        Set objManager = Document.CreateElement("OPTION")
        objManager.Text = objOption.Text
        objManager.Value = objOption.Value
        ManagerDropDown.Add(objManager)
        If objManager.Value = strManagerLDAP Then
          objManager.Selected = True
        End If
      Next
    
      ' Fill in the other missing details
      JobTitle.Value = objUser.title
      Department.Value = objUser.department
    End Sub
    
    Sub SaveButton
      ' Just write all three values out
      strStaffLDAP = StaffDropDown.Value
      Set objUser = GetObject(strStaffLDAP)
    
      If JobTitle.value <> "" Then
        objUser.Put "title", JobTitle.Value
      End If
      If Department.value <> "" Then
        objUser.Put "department", Department.Value
      End If
    
      ' Manager is slightly more tricky as we have to strip the LDAP:// bit off the ADsPath
      strManager = ManagerDropDown.Value
      If strManager <> "" Then
        strManager = Mid(strManager, 8)
      End If
      objUser.Put "manager", strManager
    
      CancelButton
      On Error Resume Next
      objUser.SetInfo
      If Err.Number = 0 Then
        Output.InnerHTML = "<p>User information updated successfully.</p>"
      Else
        Output.InnerHTML = "<P>Error while setting user information: " & Err.Description & "</p>"
      End If
    End Sub
    
    Sub CancelButton
      Output.InnerHTML = ""
    
      ' Reset the staff picker to the Select... option
      bolSelected = True
      For Each objOption in StaffDropDown.Options
        objOption.Selected = bolSelected
        bolSelected = False
      Next
    End Sub
    
    Sub Window_Onload
      Const ADS_SCOPE_SUBTREE = 2
    
      self.ResizeTo 439,216
    
      Set objConnection = CreateObject("ADODB.Connection")
      Set objCommand =   CreateObject("ADODB.Command")
      objConnection.Provider = "ADsDSOObject"
      objConnection.Open "Active Directory Provider"
      Set objCommand.ActiveConnection = objConnection
    
      objCommand.Properties("Page Size") = 1000
      objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 
    
      objCommand.CommandText = _
        "SELECT Name, ADsPath FROM 'LDAP://" & strDomainPath & "' WHERE objectCategory='user' ORDER BY Name"
      Set objRecordSet = objCommand.Execute
    
      objRecordSet.MoveFirst
      Do Until objRecordSet.EOF
        Set objOption = Document.createElement("OPTION")
        objOption.Text = objRecordSet.Fields("Name").Value
        objOption.Value = objRecordSet.Fields("ADsPath").Value
        StaffDropDown.Add(objOption)
        objRecordSet.MoveNext
      Loop
    End Sub
    </script>
    
    <body>
    Name: <select name="StaffDropDown" onChange="StaffSelected">
    <option value="">Select ...</option>
    </select>
    <span id="Output"></span>
    </body>



    ARM سپاسگزاری کرده است.

  15. #45
    نام حقيقي: 1234

    مدیر بازنشسته
    تاریخ عضویت
    Jul 2009
    محل سکونت
    5678
    نوشته
    5,634
    سپاسگزاری شده
    2513
    سپاسگزاری کرده
    272
    Remove Active Directory Domain Controller Metadata


    The GUI Metadata Cleanup Utility removes Active Directory domain controller metadata left behind after a domain controller is removed improperly or unsuccessfully (typically a dcpromo /forceremoval). This script was written by Clay Perrine and submitted by Kurt Hudson, both of Microsoft.

    This script queries Active Directory to locate all domain controllers in the domain. It then displays these domain controllers in an input box that reads “Enter the computer name to be removed.” Type the name of the domain controller and click okay; the metadata for the hostname that was entered will be removed from the directory.
    VBScript
    کد:
    REM    ==========================================================
    REM                GUI Metadata Cleanup Utility
    REM             Written By Clay Perrine
    REM                          Version 2.5
    REM    ==========================================================
    REM     This tool is furnished "AS IS". NO warranty is expressed or Implied.
    
    on error resume next
    dim objRoot,oDC,sPath,outval,oDCSelect,objConfiguration,objContainer,errval,ODCPath,ckdcPath,myObj,comparename
    
    rem =======This gets the name of the computer that the script is run on ======
    
    Set sh = CreateObject("WScript.Shell")
    key= "HKEY_LOCAL_MACHINE"
    computerName = sh.RegRead(key & "\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName\ComputerName")
    
    rem === Get the default naming context of the domain====
    
    set objRoot=GetObject("LDAP://RootDSE")
    sPath = "LDAP://OU=Domain Controllers," & objRoot.Get("defaultNamingContext")
    
    rem === Get the list of domain controllers====
    
    Set objConfiguration = GetObject(sPath)
    For Each objContainer in objConfiguration
        outval = outval & vbtab &  objContainer.Name & VBCRLF
    Next
    outval = Replace(outval, "CN=", "")
    
    rem ==Retrieve the name of the broken DC from the user and verify it's not this DC.===
    
    oDCSelect= InputBox (outval," Enter the computer name to be removed","")
    comparename = UCase(oDCSelect)
    
    if comparename = computerName then
        msgbox "The Domain Controller you entered is the machine that is running this script." & vbcrlf & _
            "You cannot clean up the metadata for the machine that is running the script!",,"Metadata Cleanup Utility Error."
        wscript.quit
    End If
    
    sPath = "LDAP://OU=Domain Controllers," & objRoot.Get("defaultNamingContext")
    Set objConfiguration = GetObject(sPath)
    
    For Each objContainer in objConfiguration
        Err.Clear
        ckdcPath = "LDAP://" & "CN=" & oDCSelect & ",OU=Domain Controllers," & objRoot.Get("defaultNamingContext")
        set myObj=GetObject(ckdcPath)
        If err.number <>0 Then
            errval= 1
        End If
    Next
    
    If errval = 1 then
        msgbox "The Domain Controller you entered was not found in the Active Directory",,"Metadata Cleanup Utility Error."
        wscript.quit
    End If
    
    abort = msgbox ("You are about to remove all metadata for the server " & oDCSelect & "! Are you sure?",4404,"WARNING!!")
    if abort <> 6 then
        msgbox "Metadata Cleanup Aborted.",,"Metadata Cleanup Utility Error."
        wscript.quit
    end if
    
    oDCSelect = "CN=" & oDCSelect
    ODCPath ="LDAP://" & oDCselect & ",OU=Domain Controllers," & objRoot.Get("defaultNamingContext")
    sSitelist = "LDAP://CN=Sites,CN=Configuration," & objRoot.Get("defaultNamingContext")
    Set objConfiguration = GetObject(sSitelist)
    For Each objContainer in objConfiguration
        Err.Clear
        sitePath = "LDAP://" & oDCSelect & ",CN=Servers," &  objContainer.Name & ",CN=Sites,CN=Configuration," & _
            objRoot.Get("defaultNamingContext")
        set myObj=GetObject(sitePath)
        If err.number = 0 Then
            siteval = sitePath
        End If    
    Next
    
    sFRSSysvolList = "LDAP://CN=Domain System Volume (SYSVOL share),CN=File Replication Service,CN=System," & _
        objRoot.Get("defaultNamingContext")
    Set objConfiguration = GetObject(sFRSSysvolList)
    
    For Each objContainer in objConfiguration
        Err.Clear
        SYSVOLPath = "LDAP://" & oDCSelect & ",CN=Domain System Volume (SYSVOL share),CN=File Replication Service,CN=System," & _
            objRoot.Get("defaultNamingContext")
        set myObj=GetObject(SYSVOLPath)
        If err.number = 0 Then
            SYSVOLval = SYSVOLPath
        End If
    Next
    
    SiteList = Replace(sSitelist, "LDAP://", "")
    VarSitelist = "LDAP://CN=Sites,CN=Configuration," & objRoot.Get("defaultNamingContext")
    Set SiteConfiguration = GetObject(VarSitelist)
    
    For Each SiteContainer in SiteConfiguration
        Sitevar = SiteContainer.Name
        VarPath ="LDAP://OU=Domain Controllers," & objRoot.Get("defaultNamingContext")
        Set DCConfiguration = GetObject(VarPath)
        For Each DomContainer in DCConfiguration
            DCVar = DomContainer.Name
            strFromServer = ""
            NTDSPATH =  DCVar & ",CN=Servers," & SiteVar & "," & SiteList
            GuidPath = "LDAP://CN=NTDS Settings,"& NTDSPATH 
            Set objCheck = GetObject(NTDSPATH)
            For Each CheckContainer in objCheck
    rem ====check for valid site paths =======================
                ldapntdspath = "LDAP://" & NTDSPATH
                Err.Clear
                set exists=GetObject(ldapntdspath)
                If err.number = 0 Then
                    Set oGuidGet = GetObject(GuidPath)
                    For Each objContainer in oGuidGet
                        oGuid = objContainer.Name
                        oGuidPath = "LDAP://" & oGuid & ",CN=NTDS Settings," & NTDSPATH  
                        Set objSitelink = GetObject(oGuidPath)
                        objSiteLink.GetInfo
                        strFromServer = objSiteLink.Get("fromServer")
                        ispresent = Instr(1,strFromServer,oDCSelect,1)
    
                        if ispresent <> 0 then
                            Set objReplLinkVal = GetObject(oGuidPath)
                            objReplLinkVal.DeleteObject(0)
                        end if
                    next
    
                    sitedelval = "CN=" & comparename & ",CN=Servers," & SiteVar & "," & SiteList
                    if sitedelval = ntdspath then
                        Set objguidpath = GetObject(guidpath)
                        objguidpath.DeleteObject(0)
                        Set objntdspath = GetObject(ldapntdspath)
                        objntdspath.DeleteObject(0)
                    end if
                End If
            next
        next
    next
    Set AccountObject = GetObject(ckdcPath)
    temp=Accountobject.Get ("userAccountControl")
    AccountObject.Put "userAccountControl", "4096"
    AccountObject.SetInfo
    Set objFRSSysvol = GetObject(SYSVOLval)
    objFRSSysvol.DeleteObject(0)
    Set objComputer = GetObject(ckdcPath)
    objComputer.DeleteObject(0)
    Set objConfig = GetObject(siteval)
    objConfig.DeleteObject(0)
    oDCSelect = Replace(oDCSelect, "CN=", "")
    msgval = "Metadata Cleanup Completed for " & oDCSelect
    msgbox  msgval,,"Notice."
    wscript.quit



    ARM سپاسگزاری کرده است.

صفحه 3 از 7 اولیناولین 1 2 3 4 5 6 7 آخرینآخرین

کلمات کلیدی در جستجوها:

پرشین نتورک

اسکریپت

نتورک ادمین

اسکریپت میکروتیک

اسکریپت ویندوز

http://forum.persiannetworks.com/f25/t31065.html

بانک اسکریپت

بانک

ادمین نتورک

اسکریپت در ویندوز

اسکریپت برای ویندوز

اسکریپت بانک

پرسین نتورکاضافه کردن پرینتر با اسکریپتconnection to dc scriptbatchفایلtelnet زدن در میکروتیکپ رسین نت ورکاسکریپت joinپرشن نتورکcloner.SendKeysبانك اسكريپاسكريپتterminalservicesprofilepath vbscriptبانک اسکرپیت

برچسب برای این موضوع

2003, 2008, 2008r2, 2911, 2960, 404, access, active, active directory, additional, admin, administrator, alias, application, archive, arp, backup, batch, bind, bios, bitlocker, browser, call, cdp, communication, computername, conference, configuration, control, crack, credentials, date, dcpromo, default gateway, delete, desktop, device, dhcp, disable, domain, domain controller, drive, email, enable, encrypt, error, failure, filter, finance, form, forum, gateway, google, gpo, group policy, gui, hardware, home page, host, html, http, img, install, ip address, ipconfig, ise, isolated, join, ldap, license, list, load, local, log off, log on to, login, loop, mac, map drive, memory, messaging, microsoft, microsoft office, monitoring, move, net stop, number, offline, page, password, personal, policy, pos, powershell, print server, problem, profile, queue, quota, ras, record, refresh, registerdns, remo, remote, remote desktop, replication, report, reset, resource kit, restart, restore, ris, role, route, run, s-1-5-21, sas, script, secure, send, serial, server, services, session, share, shared, sharepoint, shutdown, sms, smtp, smtp server, software, span, split, sql, start, startup, static, stop, support, switch, system center, target, telephone, telnet, test, ttl, update, user, username, فونت, فروش, لاگین, مایکروسافت, مدارک, نتورک, نصب شده, هستش, ویندوز, ویندوز 7, ورود, یوزر, کلاینتها, کمک, کانکشن, کار, کارها, کاربران, کردن, گوگل, گروپ پالیسی, پیشنهاد, پارتیشن, پرینتر, پرشین, پشتیبان گیری, vpn, wallpaper, wan, warning, web, web server, webpage, website, windows, windows server, windows server 2003, windows update, windows xp, word, wrt, wss, xml, آشنایی, اولین, اتوماتیک, اجرای, اسکریپت, اشتراک, اطلاعات, بک آپ, برنامه, تلنت, تنظیمات, تست, حداقل, حذف, خودکار, خودش, دومین, دانلود, درخواست, دستور, روی, روش, راهنمایی, رایگان, سوییچ, سیستم, سیستم سرور, سایت, شیر شده

نمایش برچسب ها

مجوز های ارسال و ویرایش

  • شما نمی توانید موضوع جدید ارسال کنید
  • شما نمی توانید به پست ها پاسخ دهید
  • شما نمی توانید فایل پیوست ضمیمه کنید
  • شما نمی توانید پست های خود را ویرایش کنید
  •