بررسی تنظیمات Load Balancing Using PCC

**OmidSystem** · 2014-01-03, 10:19 PM

با سلام

این سناریو جهت لود بالانسینگ راهندازی کردم اگر ممکنه دوستان یه برسسی بکنن ببینن اشکال کارم کجاست بالانس انجام نمیشه ولی اگه لینکی قطع بشه لینک بعدی جایگزین میشه

هدف بالانس یه خط pppoe و دو خط اینترنت با آی پی پابلیک

کد:

/interface ethernet
set 0 arp=enabled auto-negotiation=yes cable-settings=default comment="=======\
    ===========================Link 66 Internet===============================\
    ===" disable-running-check=yes disabled=no full-duplex=yes l2mtu=1600 \
    mac-address=01:15:F0:D8:78:87 mtu=1500 name=WAN-66 speed=100Mbps
set 1 arp=enabled auto-negotiation=yes cable-settings=default comment="=======\
    ===========================Link 67 Internet===============================\
    ===" disable-running-check=yes disabled=no full-duplex=yes mac-address=\
    44:E2:31:82:53:30 mtu=1500 name=WAN-67 speed=100Mbps
set 2 arp=enabled auto-negotiation=yes cable-settings=default comment="=======\
    ===========================Local Internet Out Lan=========================\
    =========" disable-running-check=yes disabled=no full-duplex=yes \
    mac-address=00:20:E1:26:1B:62 mtu=1500 name=LOCAL-OUT speed=100Mbps
set 3 arp=enabled auto-negotiation=yes cable-settings=default comment="=======\
    ===========================ADSL +2 Device=================================\
    =" disable-running-check=yes disabled=no full-duplex=yes mac-address=\
    00:12:85:10:92:4B mtu=1500 name=WAN-ADSL speed=100Mbps








/interface pppoe-client
add ac-name="" add-default-route=no allow=pap,chap,mschap1,mschap2 comment="==\
    ================================PPPoE LINK================================\
    ==" dial-on-demand=no disabled=no interface=WAN-ADSL max-mru=1480 \
    max-mtu=1480 mrru=disabled name=pppoe-link password=1 profile=default \
    service-name="" use-peer-dns=no user=1




/ip address
add address=192.168.2.1/24 comment="==================================Local La\
    n==================================" disabled=no interface=LOCAL-OUT \
    network=192.168.2.0
add address=192.168.91.2/24 comment="==================================ADSL+2 \
    Lan==================================" disabled=no interface=WAN-ADSL \
    network=192.168.91.0
add address=192.16.0.2/32 comment="==================================WAN 66=\
    =================================" disabled=no interface=WAN-66 network=\
    192.16.0.1
add address=192.16.2.2/32 comment="==================================WAN 67\
    ==================================" disabled=no interface=WAN-67 network=\
    192.16.2.1




/ip dhcp-server config
set store-leases-disk=5m
/ip dhcp-server network
add address=192.168.2.0/24 dhcp-option="" dns-server=\
    217.218.127.127,4.2.2.4,8.8.8.8 gateway=192.168.2.1 ntp-server="" \
    wins-server=""
/ip dns
set allow-remote-requests=yes cache-max-ttl=1w cache-size=20000KiB \
    max-udp-packet-size=4096 servers=217.218.128.128,8.8.8.8,4.2.2.4




/ip firewall mangle
add action=mark-connection chain=input disabled=no in-interface=WAN-66 \
    new-connection-mark=WAN-66_conn passthrough=yes
add action=mark-connection chain=input disabled=no in-interface=WAN-67 \
    new-connection-mark=WAN-67_conn passthrough=yes
add action=mark-connection chain=input disabled=no in-interface=pppoe-link \
    new-connection-mark=WAN-ADSL_conn passthrough=yes
add action=mark-connection chain=input disabled=no in-interface=pppoe-202 \
    new-connection-mark=WAN-ADSL_conn passthrough=yes
add action=mark-connection chain=input disabled=no in-interface=pppoe-921 \
    new-connection-mark=WAN-ADSL_conn passthrough=yes
add action=mark-connection chain=input disabled=no in-interface=pppoe-554 \
    new-connection-mark=WAN-ADSL_conn passthrough=yes
add action=mark-routing chain=output connection-mark=WAN-66_conn disabled=no \
    new-routing-mark=to_WAN-66 passthrough=yes
add action=mark-routing chain=output connection-mark=WAN-67_conn disabled=no \
    new-routing-mark=to_WAN-67 passthrough=yes
add action=mark-routing chain=output connection-mark=WAN-ADSL_conn disabled=\
    no new-routing-mark=to_WAN-ADSL passthrough=yes
add action=mark-connection chain=prerouting disabled=no dst-address-type=\
    !local in-interface=LOCAL-OUT new-connection-mark=WAN-66_conn \
    passthrough=yes per-connection-classifier=both-addresses-and-ports:3/0
add action=mark-connection chain=prerouting disabled=no dst-address-type=\
    !local in-interface=LOCAL-OUT new-connection-mark=WAN-67_conn \
    passthrough=yes per-connection-classifier=both-addresses-and-ports:3/1
add action=mark-connection chain=prerouting disabled=no dst-address-type=\
    !local in-interface=LOCAL-OUT new-connection-mark=WAN-ADSL_conn \
    passthrough=yes per-connection-classifier=both-addresses-and-ports:3/2
add action=mark-connection chain=prerouting connection-mark=WAN-66_conn \
    disabled=no in-interface=LOCAL-OUT new-connection-mark=WAN-66_conn \
    passthrough=yes
add action=mark-connection chain=prerouting connection-mark=WAN-67_conn \
    disabled=no in-interface=LOCAL-OUT new-connection-mark=WAN-67_conn \
    passthrough=yes
add action=mark-connection chain=prerouting connection-mark=WAN-ADSL_conn \
    disabled=no in-interface=LOCAL-OUT new-connection-mark=WAN-ADSL_conn \
    passthrough=yes
/ip firewall nat
add action=masquerade chain=srcnat disabled=no out-interface=WAN-66
add action=masquerade chain=srcnat disabled=no out-interface=WAN-67
add action=masquerade chain=srcnat disabled=no out-interface=pppoe-link






/ip route
add check-gateway=ping disabled=no distance=1 dst-address=0.0.0.0/0 gateway=\
    192.16.0.1 routing-mark=to_WAN-66 scope=30 target-scope=10
add check-gateway=ping disabled=no distance=1 dst-address=0.0.0.0/0 gateway=\
    192.16.2.1 routing-mark=to_WAN-67 scope=30 target-scope=10
add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=pppoe-link \
    routing-mark=to_WAN-ADSL scope=30 target-scope=10
add check-gateway=ping disabled=no distance=1 dst-address=0.0.0.0/0 gateway=\
    pppoe-link scope=30 target-scope=10
add check-gateway=ping disabled=no distance=2 dst-address=0.0.0.0/0 gateway=\
    192.16.0.1 scope=30 target-scope=10
add check-gateway=ping disabled=no distance=3 dst-address=0.0.0.0/0 gateway=\
    192.16.2.1 scope=30 target-scope=10

موضوعات مشابه:

**OmidSystem** · 2014-01-04, 12:39 AM

با تشکر از دوستان خودم حلش کردم مشکل از اینجا بود

کد:

add action=mark-routing chain=prerouting connection-mark=WAN-66_conn disabled=\
    no in-interface=LOCAL-OUT new-routing-mark=to_WAN-66 passthrough=yes
add action=mark-routing chain=prerouting connection-mark=WAN-67_conn disabled=\
    no in-interface=LOCAL-OUT new-routing-mark=to_WAN-67 passthrough=yes
add action=mark-routing chain=prerouting connection-mark=WAN-ADSL_conn \
    disabled=no in-interface=LOCAL-OUT new-routing-mark=to_WAN-ADSL \
    passthrough=yes

اینم عکس از نتیجه موفقیت آمیز لود بالاسینگ

http://upload.tehran98.com/upme/uplo...6f70293a91.jpg

**M-r-r** · 2014-01-04, 12:41 AM

روی Valid IP هاتون میتونید تجمیع ترافیک رو داشته باشید ؟

**OmidSystem** · 2014-01-04, 01:25 AM

کلا موقع دانلود یا لود سایت از سرور های ایرانی هیچ مشکلی ندارم و کل پهنای باند 3 تا لینک دریافت میشه .

یکم توی دانلود از هاست های برون مرزی مشکل داره هنوز ولی در کل راضیم فعلا ازش

**mr-ehsan** · 2014-01-04, 10:59 AM

سلام
بعد از راه اندازی لود بالانس ، لود CPU روی چند هستش ؟
مدل روتر رو هم بفرمایید ممنون میشم

**hexman** · 2014-01-04, 11:08 AM

وقتی یکی از لینکهاتون قطع میشه وضعیت چطوری میشه؟

**OmidSystem** · 2014-01-04, 01:07 PM

سلام Mikrotik OS v5.26 x86 - کرک شده - روتر نیست- PC مشخصات سیستم_( CUP Dull core رم 2 گیگ ) بالاست چک نکردم ببینم چند درصد میشه ولی چک می کنمش .

اگه لینکی قط بشه توازون بین دوتا لینک دیگه بر قرار میشه اولویت بندی روت ها مشخص می کنه لینک اول که قطع بشه کدوم لینک جایگیزین بشه .

موضوع: بررسی تنظیمات Load Balancing Using PCC

پیوند

ابزارهای موضوع

نمایش

بررسی تنظیمات Load Balancing Using PCC

کلمات کلیدی در جستجوها:

DNS Server IP Address 217.218.127.127

برچسب برای این موضوع

مجوز های ارسال و ویرایش