تعمیر میکروتیک RB751U-2HnD

[MasoudShGh]

با عرض سلام،
من امروز برای تمرین با میکروتیک یک RB751U-2HnD خریدم، ولی یک ساعت نشده انگار خرابش کردم.
کنار دستگاه یک کاغذ بود که نوشته بود برای کار با پورت USB روتراُاس را آپدیت کنید. من هم با بعد از دانلود فایل از سایتش اونو آپدیت کردم. ولی بعد از رفتن به صفحه ی وبش دیدم تبلیغات اون شرکتی که ازش خریدم هنوز روش مونده، منم گفتم حتماً یک بار باید رست کنم تا آپدیت کامل بشه، خلاصه با خوندن ویکی میکروتیک دستگاه رو رست کردم...... ولی حالا که دستگاه رو روشن می کنم وایرلس فعال نمیشه و اگه با کابل هم وصل می کنم چراغ پورت مربوطه روشن میشه ولی با Winbox نمی تونم وارد بشم، حتی صفحه وبش هم نمی یاد.
دوستان اگه ممکنه منو راهنمایی کنید...

---

موضوعات مشابه:

• راهنمایی در مورد کانفیگ میکروتیک RB2011 UAS-2HnD-IN؟
• تعمیر روتر بورد میکروتیک ؟؟
• بوت نشدن میکروتیک RB751U-2HnD
• تعهد نامه جديد

---

[amirkhatam]

دوست عزیز شما اول از برق جدا کن دستگاه رو
بعد بزن به برق و تا بالا نیامده سریع با یک خودکار یا یک جسم نوک تیز به مدت 2 دقیقه محلی که تحت عنوان RES مشخص شده را نگه دار و بعدش ول کن و صبر کن تا بیاد بالا با وین باکس بزن بهش ببین میشه !

[MasoudShGh]

ممنون از پاسختون،
ولی مثل حالت قبلی مونده و نمی تونم کانکت بشم.

وقتی کارت شبکه رو تو حالت Manual قرار میدم موقع وصل شدن این ارور رو میده:

Could not connect to 192.168.88.1 - no response!

و وقتی که کارت رو تو حالت Auto قرار میدم این ارور رو میده:

Could not connect to 192.168.88.1 - no response!

البته برا دوستمم خریدم و الان میکروتیک اون که سالمم هست پیشه منه، میشه تنظیمات اونو با Netinstall برداشت و روی دستگاه من زد؟


ویرایش:
اولین بار که با Winbox لاگین کردم یه پیغام داد که انگار می خواست تنظیمات اولیه رو با اسکریپت بزنه، منم از اون اسکریپت یه کپی براشتم، حالا اون اسکریپت هم میتونه لازم بشه؟
اسکریپت:

#| ether1 is renamed to ether1-gateway
#| DHCP client and masquerade is set on ether1-gateway
#| ether2 is renamed to ether2-master-local and configured as switch master port for ether3-ether5
#| ether2-master-local and wlan1 are bridged
#| wireless is set as access point in 2412MHz using both chains and extension channel enabled.
#| IP address 192.168.88.1/24 and DHCP server is set on bridge interface
#| DHCP servers address pool is 192.168.88.10-192.168.88.254

:global action;
:local dhcpEnabled 0;
:local wirelessEnabled 0;

#check for wireless and dhcp packages
:if ([:len [/system package find name="dhcp" !disabled]] != 0) do={
    :set dhcpEnabled 1;
}
:if ([:len [/system package find name="wireless" !disabled]] != 0) do={
    :set wirelessEnabled 1;
}

#-------------------------------------------------------------------------------
# Apply configuration.
# these commands are executed after installation or configuration reset
#-------------------------------------------------------------------------------
:if ($action = "apply") do={
# wait for interfaces
    :while ([/interface ethernet find] = "") do={ :delay 1s; };
    :if ( $wirelessEnabled = 1) do={
# wait for wireless
        :local count 0;
        :while ([/interface wireless find] = "") do={ 
            :set count ($count +1);
            :if ($count = 60) do={
                :log warning "DefConf: Unable to find wireless interface"; 
                /ip address add address=192.168.88.1/24 interface=ether1;
                /quit
            }
            :delay 1s;
        };
        /interface wireless set wlan1 mode=ap-bridge band=2ghz-b/g/n ht-txchains=0,1 ht-rxchains=0,1 \
            disabled=no country=no_country_set wireless-protocol=any
        /interface wireless set wlan1 channel-width=20/40mhz-ht-above ;
    }

    /interface set ether1 name="ether1-gateway";
    :if ( $dhcpEnabled = 1) do={
        /ip dhcp-client add interface=ether1-gateway disabled=no comment="default configuration";
    }

    /interface {
        set ether2 name=ether2-master-local;
        set ether3 name=ether3-slave-local;
        set ether4 name=ether4-slave-local;
        set ether5 name=ether5-slave-local;
    }
    /interface ethernet {
        set ether3-slave-local master-port=ether2-master-local;
        set ether4-slave-local master-port=ether2-master-local;
        set ether5-slave-local master-port=ether2-master-local;
    }

    /interface bridge
        add name=bridge-local disabled=no auto-mac=no protocol-mode=rstp;
    :local bMACIsSet 0;
    :foreach k in=[/interface find] do={
        :local tmpPortName [/interface get $k name];
        :if (!($tmpPortName~"bridge"  || $tmpPortName~"ether1"|| $tmpPortName~"slave")) do={
            :if ($bMACIsSet = 0) do={
                :if ([/interface get $k type] = "ether") do={
                    /interface bridge set "bridge-local" admin-mac=[/interface ethernet get $tmpPortName mac-address];
                    :set bMACIsSet 1;
                }
            }
            /interface bridge port
                add bridge=bridge-local interface=$tmpPortName;
        }
    }

    /ip address add address=192.168.88.1/24 interface=bridge-local comment="default configuration";
    :if ($dhcpEnabled = 1) do={
        /ip pool add name="default-dhcp" ranges=192.168.88.10-192.168.88.254;
        /ip dhcp-server
            add name=default address-pool="default-dhcp" interface=bridge-local disabled=no;
        /ip dhcp-server network
            add address=192.168.88.0/24 gateway=192.168.88.1 dns-server=192.168.88.1 comment="default configuration";
    }
    /ip firewall nat add chain=srcnat out-interface=ether1-gateway action=masquerade comment="default configuration"
    /ip firewall {
        filter add chain=input action=accept protocol=icmp comment="default configuration"
        filter add chain=input action=accept connection-state=established comment="default configuration"
        filter add chain=input action=accept connection-state=related comment="default configuration"
        filter add chain=input action=drop in-interface=ether1-gateway comment="default configuration"
    }
    /tool mac-server disable [find];
    /tool mac-server mac-winbox disable [find];
    :foreach k in=[/interface find] do={
        :local tmpName [/interface get $k name];
        :if (!($tmpName~"ether1")) do={
            /tool mac-server add interface=$tmpName disabled=no;
            /tool mac-server mac-winbox add interface=$tmpName disabled=no;
        }
    }
    /ip neighbor discovery set [find name="ether1-gateway"] discover=no
    /ip dns {
        set allow-remote-requests=yes
        static add name=router address=192.168.88.1
    }

}

#-------------------------------------------------------------------------------
# Revert configuration.
# these commands are executed if user requests to remove default configuration
#-------------------------------------------------------------------------------
:if ($action = "revert") do={
# remove wan port protection
    /ip firewall {
        :local o [nat find comment="default configuration"]
        :if ([:len $o] != 0) do={ nat remove $o }
        :local o [filter find comment="default configuration"]
        :if ([:len $o] != 0) do={ filter remove $o }
    }
    /tool mac-server remove [find interface!=all]
    /tool mac-server set [find] disabled=no
    /tool mac-server mac-winbox remove [find interface!=all]
    /tool mac-server mac-winbox set [find] disabled=no 
# reset wan ports;
    /ip neighbor discovery set [find name="ether1-gateway"] discover=yes
    /interface set "ether1-gateway" name=ether1;
    :if ($dhcpEnabled = 1) do={
        :local o [/ip dhcp-server network find comment="default configuration"]
        :if ([:len $o] != 0) do={ /ip dhcp-server network remove $o }
        :local o [/ip dhcp-server find name="default" address-pool="default-dhcp" interface="bridge-local" !disabled]
        :if ([:len $o] != 0) do={ /ip dhcp-server remove $o }
        /ip pool {
            :local o [find name="default-dhcp" ranges=192.168.88.10-192.168.88.254]
            :if ([:len $o] != 0) do={ remove $o }
        }
        :local o [/ip dhcp-client find comment="default configuration"]
        :if ([:len $o] != 0) do={ /ip dhcp-client remove $o }
    }
    /ip dns {
        set allow-remote-requests=no
        :local o [static find name=router address=192.168.88.1]
        :if ([:len $o] != 0) do={ static remove $o }
    }
    /ip address {
        :local o [find comment="default configuration"]
        :if ([:len $o] != 0) do={ remove $o }
    }
# remove switch
    /interface set ether2-master-local name=ether2;
    /interface ethernet set ether3-slave-local master-port=none;
    /interface set ether3-slave-local name=ether3;
    /interface ethernet set ether4-slave-local master-port=none;
    /interface set ether4-slave-local name=ether4;
    /interface ethernet set ether5-slave-local master-port=none;
    /interface set ether5-slave-local name=ether5;
    /interface bridge port remove [find bridge="bridge-local"]
    /interface bridge remove [find name="bridge-local"]
    :if ($wirelessEnabled = 1) do={
        /interface set [find name~"wlan1"] name=wlan1
        /interface wireless reset-configuration wlan1
    }

}

[amirkhatam]

اقا شما ریست کردی دستگاه رو پس دیگه 88.1 جواب نمیده با مک وصل شید ... تا وقتی هم ای پی ندادید به روتر ویندوز رو اتوماتیک بزارید ...
نه اون اسکریپت چیز خواصی نیست ...

شما با یک سیستم دیگه هم چک کنید

اها راستی با پورت 2 و یا 3 . 4 . 5 هم وصل شید !
امکانات زیادی هست باید همه کنترل شن ..

اما حتما چک کنید با یک سیستم دیگه شخصا دیدم بعضی وقت ها روتر قاطی کرده و جواب به یک سیستم خواص نداده و علت هم ویندوز اون کامپیوتر بوده

[MasoudShGh]

خیلی خیلی ممنون دوست عزیز! دستتون درد نکنه...
بالاخره تونستم وصل شم.
ببخشید میشه بگید که چطوری میشه تنظیمات اون میکروتیک سالم رو برداشت و رو میکروتیک ماله من زد؟ چون که انگار همه چی رست شده.

ویرایش:
تو ویکیه میکروتیک اینو پیدا کردم، امتحان کنم ببینم جواب میده...
http://wiki.mikrotik.com/wiki/Manual...ion_Management

با تشکر از امیر خاتم عزیز بابت راهنمایی.

[amirkhatam]

اگر بک اپ داشته باشین ، بله میتونین و توی وین باکس یک قسمت هست به نام File و وقتی ریست کردین شاید همچین فایلی مونده باشه :
auto-before-reset.backup
و اگر هم این نبود شما برین تو قسمت File اون میکروتیک و یک Backup بگیرید
بعد برین تو مال خودتون Restore کنید

و البته اون کانفیگ روی قبلی ، کانفیگ دیفالت بوده از قسمت System برید به Reset Configuration و ریست کنید تا اطلاعات و کانفیگ دیفالت برگرده ...

خواهش میکنم دوست عزیز !

کنار دستگاه یک کاغذ بود که نوشته بود برای کار با پورت USB روتراُاس را آپدیت کنید. من هم با بعد از دانلود فایل از سایتش اونو آپدیت کردم.

اقا جریان این برگه چیه ؟ ! ! ! تو جعبه میکروتیک فقط یک روتر هست با یک ادا÷تور تازه شما برای اپدیت هم فقط از سایت میکروتیک قسمت Download جدید ترین روتر او اس رو با فرمت NPK دانلود کن با FTP یا همون قسمت ّFile بریزش رو دستگاه و از قسمت System روی Reboot بزن تا نصب شه ..

نکته برای ارسال NPK یا هر فایلی رو دسگاه کافیه Drog and drop کنید از ویندوز توی وینباکس (File)

[MasoudShGh]

بالاخره دیشب با راهنمایی شما و ویکیه میکروتیک تونستم حلش کنم، از میکروتیک سالم تنظیماتو برداشتم و رو میکروتیک خودم ریختم...

اون برگه ای که گفتم یک تیکه کاغذ بود تو جعبه میکروتیک و این روش نوشته شده بود:

To use the USB port, please upgrade RouterOS software to the latest version

برا آپدیت هم همونطور که شما فرمودید فایل NPK رو دانلود کردم و Drag & Drop کردم تو Winbox و بعد از راه اندازی دوباره دیدم که تغییری نکرد، ریست کردم و ....

[mehrzadmo]

ممکنه فایلی رو ریختین مربوط به این روتربورد نبوده باشه .

[MasoudShGh]

ممنون از پاسختون،
تو صفحه دانلود میکروتیک از لیست Devices گزینه ی RB700 series رو انتخاب کردم بعد فایل NPK رو دانلود کردم و ریختم رو دستگاه و آپدیت کردم.
اشتباه من این بود که فکر کردم بعد از آپدیت کردن احتمالاً تمام تنظیمات رست میشه و عکس و اسم اون شرکت فروشنده حذف میشه، در حالی که اونطوری نشد.

[amirkhatam]

سلام .. این که نوشته

To use the USB port, please

upgrade

RouterOS software to the latest version

یعنی : برای استفاده از پورت USB به اخرین نسخه به روز رسانی کنید !

و راه هم همنه یک بار دیگه فایل NPK مخصوص رو Drag & Drop کنید بعد با مراجعه به System و reboot .................

[MasoudShGh]

منم برای همین آپگرید کردم، فقط نمی دونستم که بعد از آپگرید همه ی تنظیمات سر جاش می مونه و اصلاً انتظار نداشتم بعد از آپدیت آرم اون شرکت رو ببینم و برای همین رست کردم و دچار درد سر شدم. ولی حالا بازم خوب شد تونسم با راهنمایی شما مشکل رو حل کنم و یک نکته هم یاد بگیرم. حالا دستگاه عین اولش شده و بخوبی کار میکنه و به جدیدترین نسخه هم آپگرید شده.
ولی بازم هر جا که میرم اسم و آرم اون شرکت رو میبینم!