script برای remote desktop

[katrin]

سلام دوستان
من به یک script احتیاج دارم که تیک remote desktop را به صورت اتوماتیک بزنه . خیلی search کردم ولی فقط یکسری bat file پیدا کردم که port را روی firewall باز میکنه مثل netsh . کسی این scriptرو در اختیار داره؟؟؟؟؟؟؟؟؟؟؟؟

---

موضوعات مشابه:

• remote desktop
• remote desktop
• remote desktop
• برنامه کار با وبکم فقط از طریق Remote Desktop کار می کنه !!!
• Remote desktop

---

[patris1]

http://msmvps.com/blogs/ad/archive/2006/07/28/enable-remote-desktop-through-a-script.aspx

Enable Remote Desktop Through a Script

Being a huge Group Policy guy I have always searched for a policy that would allow me to turn on or off Remote Desktop on clients and servers. Well there is no Group Policy that currently does that. I do however have VB script that can be used to enable Remote Desktop on Windows 2000, XP, and Server 2003 and then of course pushed out via Remote Desktop.

To use copy the code below and paste into a file with a text file with a .vbs extension. This will work for the local machine. Just replace the perion part that is mentioned in this string to another computer name if you want have it work on one machine

Const ENABLE_CONNECTIONS = 1
 
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}\\" & strComputer & "\root\cimv2")

Set colItems = objWMIService.ExecQuery _
    ("Select * from Win32_TerminalServiceSetting")

For Each objItem in colItems
    errResult = objItem.SetAllowTSConnections(ENABLE_CONNECTIONS)
Next

By the way if you want to turn off Remote Desktop just change the 1 in this line of code

Const ENABLE_CONNECTIONS = 1
 
to a 0.

[patris1]

Submitted By: Jeremy McGuinn
Enables Remote Desktop on any computer including a remote computer


VBScript

Dim strPC
strPC = InputBox("What machine would you like to connect to and enable remote desktop?", _
    "Connect to Server")
set oRD = GetObject("winmgmts:{impersonationLevel=impersonate}!//"& strPC & _
    "/root/cimv2").InstancesOf("Win32_TerminalServiceSetting")
For each srv in oRD
    If srv.AllowTSConnections <> 1 Then
        result=srv.SetAllowTSConnections(1)
        MsgBox "Remote Desktop Now enabled"
    Else
        MsgBox "Remote Desktop is already enabled"
    end If
Next

[patris1]

Submitted By: Andre Zouain
Enables remote desktop connections on the target computer

VBScript

'This script enables remote desktop connections on the target host
'very useful for support when you don't have RDM
'Scripted by Andre Zouain

Const ENABLE = 1
Const ENABLE_CONNECTIONS = 1
 
strComputer = InputBox("Hostname")
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}\\" & strComputer & "\root\cimv2")

Set colItems = objWMIService.ExecQuery _
    ("Select * from Win32_Terminal Where TerminalName = 'Accounting'")

For Each objItem in colItems
    errResult = objItem.Enable(ENABLE)
Next

Set colItems = objWMIService.ExecQuery _
    ("Select * from Win32_TerminalServiceSetting")

For Each objItem in colItems
    errResult = objItem.SetSingleSession(ENABLE)
    errResult = objItem.SetAllowTSConnections(ENABLE_CONNECTIONS)
Next

[patris1]

Submitted By: Shawn Stugart
Enables or disables Remote Desktop on a specified computer

VBScript

const HKEY_LOCAL_MACHINE = &H80000002
strComputer = InputBox("Enter the MACHINE NAME on which you would like to enable or disable Remote Desktop:")

If strComputer = "" Then
  WScript.Quit
End If

Set StdOut = WScript.StdOut

On Error Resume Next

Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" &_ 
strComputer & "\root\default:StdRegProv")
If Err.Number <> 0 Then
  WScript.Echo "An error has occurred.  You may have mistyped the computer name." 
  WScript.Quit
End If

strKeyPath = "SYSTEM\CurrentControlSet\Control\Terminal Server"
strValueName = "fDenyTSConnections"

oReg.GetDWORDValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,dwValue

If dwValue = 1 Then
  prompt = MsgBox ("Remote Desktop is Currently disabled.  Do you want to ENABLE it?", vbYesNo)
  If prompt = vbYes then
    dwValue = 0
    oReg.SetDWORDValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,dwValue 
     WScript.Echo "Remote Desktop is now ENABLED on " & strComputer
    WScript.Quit
  ElseIf prompt = vbNo then
    WScript.Echo "Remote Desktop is still DISABLED."
   Wscript.Quit 
  End If
ElseIf dwValue = 0 then
  prompt = MsgBox ("Remote Desktop is Currently ENABLED.  Do you want to DISABLE it?", vbYesNo)
  If prompt = vbYes then
    dwValue = 1
    oReg.SetDWORDValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,dwValue
    WScript.Echo "Remote Desktop is now DISABLED on " & strComputer
    WScript.Quit
  ElseIf prompt = vbNo then
    WScript.Echo "Remote Desktop is still ENABLED." 
    WScript.Quit
  End If
End If

[patris1]

Submitted By: Martijn Haverhoek
Enables Terminal Services on a group of computers. The file Computers.txt should contain the names of the computers on which to enable remote desktop connections

VBScript

On Error Resume Next

Const ENABLE_CONNECTIONS = 1
Const FOR_WRITING = 2
Const FOR_READING = 1

Set objFso = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("WScript.Shell")

Set oList = objFso.OpenTextFile("computers.txt",FOR_READING)
Do While Not oList.AtEndOfStream
strComputer = oList.ReadLine

If CheckIfClientExists(strComputer) = True Then
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}\\" & strComputer & "\root\cimv2")

Set colItems = objWMIService.ExecQuery _
    ("Select * from Win32_TerminalServiceSetting")

For Each objItem in colItems
    errResult = objItem.SetAllowTSConnections(ENABLE_CONNECTIONS)
Next
End If
Loop


Function CheckIfClientExists(strComputer)
Const TEMPFOLDER = 2

Dim oTS, oFile
Dim sTempFile, sTempFolder, sReturn

CheckIfClientExists = False
Set sTempFolder = objFso.GetSpecialFolder(TEMPFOLDER)
sTempFile = objFso.GetTempName
sTempFile = sTempFolder & "\" & sTempFile

objShell.Run "cmd /c ping -n 2 -l 8 " & strComputer & ">" & sTempFile,0,True

Set oFile = objFso.GetFile(sTempFile)
set oTS = oFile.OpenAsTextStream(FOR_READING)
do while oTS.AtEndOfStream <> True
sReturn = oTS.ReadLine
if instr(sReturn, "Reply")>0 then
CheckIfClientExists = True
Exit Do
End If
Loop

ots.Close
oFile.delete
End Function

[patris1]

در آخر خواهشی كه دارم ، ننویسید خیلی گشتم ولی پیدا نکردم
اینها نتجیه ۱۰ دقیقه گشتن بود
با تشکر و سپاس

[katrin]

مرسی ولی اگه عمل کرد مهمه من چند تا از این ها را زدم ولی درست عمل نکرده

[mahyar49]

مرسی ولی اگه عمل کرد مهمه من چند تا از این ها را زدم ولی درست عمل نکرده

سلام
من دوتا رو به صورت آزمایشی تست کردم و خوب هم جواب گرفتم
فقط بخاطر داشته باش که با پسوند vbs سیو کنی
به صورت نمونه:

http://www.2shared.com/file/9779480/a38dfb02/remote_desktop_enable.html

patris1 کارش درسته...